home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (DO)
/
Peeker Nr. 15 (1986)(Verlag, Dr. Alfred Huethig)(DE).zip
/
Peeker Nr. 15 (1986)(Verlag, Dr. Alfred Huethig)(DE).do
/
REELL.8.bas
< prev
next >
Wrap
BASIC Source File
|
1996-12-24
|
1KB
|
27 lines
100 REM +----------------------+
110 REM ! !
120 REM ! Applesoft-Konstanten !
130 REM ! !
140 REM +----------------------+
150 TEXT : HOME : HTAB 10: PRINT "APPLESOFT-KONSTANTEN": PRINT : PRINT
160 PRINT "NAME" SPC( 11)"WERT" SPC( 8)"SPEICHER": GOSUB 300
170 FOR K = 1 TO 13: READ A$,A
180 GOSUB 200: NEXT : GOSUB 300
190 PRINT : PRINT "MIN.INT IST UNGENAU, WEIL BYTE 5 FEHLT.": END
200 D = 0: FOR I = 1 TO 5
210 Z(I) = PEEK(A +I -1): NEXT
220 V$ = "+": IF Z(2) >127 THEN V$ = "-"
230 IF Z(2) <128 THEN Z(2) = Z(2) +128
240 FOR I = 1 TO 4:D = D +Z(I +1) *256 ^ -I: NEXT
250 D = D *2 ^(Z(1) -128)
260 PRINT A$;: HTAB 11: PRINT V$;:D$ = STR$(D): IF INT(D) = D THEN D$ = D$ +"."
270 IF D <1 THEN D$ = "0" +D$
280 IF LEN(D$) <11 THEN D$ = D$ +"0": GOTO 280
290 PRINT D$;: HTAB 25: PRINT A" BIS "A +4: RETURN
300 FOR I = 1 TO 39: PRINT "-";: NEXT : PRINT : RETURN
310 DATA MIN.INT,57598,1,59667
320 DATA SQR(1/2),59693,SQR(2),59698
330 DATA -1/2,59703,LN(2),59708
340 DATA 10,59984,MILLIARDE,60692
350 DATA 1/2,61028,2LG(E),61147
360 DATA PI/2,61542,2*PI,61547,1/4,61552